How to Convert a Clipper 5.2e application to Harbour

This article is written in in response to a comment left on Clipper... Clipper.. Clipper by Terry Carrol on 3rd July 2011 who asked

I’d like to know if there is an easy migration from Clipper to something else that I could make my Clipper program work on a 64-bit machine..."

As you are probably aware, Clipper apps being 16-bits cannot run on 64-bits Windows 7. For it to do so, it must be converted to 32-bits by using the Harbour or  xHarbour. I had previously show how to do so in Migrating from CA-Clipper 5.2e to xHarbour (Part I), a 3-part series. So this article focuses on using Harbour 2.1

Step 1 - Convert your Clipper link (*.lnk) file to  Harbour Project File (*.hbp)
Step 2 - Use Hbmk2 to compile the .hbp file

Step 1

1.1 Let us start by looking a Blinker link file of one of my actual Clipper project

BLINKER INCREMENTAL OFF
BLINKER EXECUTABLE COMPRESS
BLINKER EXECUTABLE CLIPPER F99
BLINKER PROCEDURE DEPTH 70
BLINKER OVERLAY OPSIZE 30
STACK 7168

FILE FC_MAIN
OUTPUT FASCALL

BEGINAREA
    FILE WRPT_GLL
    FILE WRPT_ARL
    FILE WRPT_ARD
    FILE WRPT_ARS
    FILE WRPT_APL
    FILE WRPT_APD
    FILE WRPT_APS
    FILE \KSLIB\CLIPLIB\UTILITY

    FILE \CLIPLIB\COMIX\CLIPMORE\52\CM52.OBJ
    ALLOCATE \CLIPLIB\COMIX\CLIPMORE\52\CM52
    FILE \CLIPLIB\COMIX\COMIX\52\CMX52.OBJ
    ALLOCATE \CLIPLIB\COMIX\COMIX\52\CMX52
ENDAREA

LIBRARY CLIPPER
LIBRARY EXTEND
LIBRARY DBFCDX
NOBELL


1.2 Convert the fascall.lnk to fascall.hbp

-ofascall4w7.exe
-w0
-es2
-rebuild

fc_main
WRPT_GLL
WRPT_ARL
WRPT_ARD
WRPT_ARS
WRPT_APL
WRPT_APD
WRPT_APS
UTILITY

Step 2


hbmk2 FASCALL.HBP

Result

You are bound to have a number of unresolved Externals, ie functions not supported by Harbour.
Once you have found alternative functions, FASCALL4W7.EXE, a true 32-bit executable will run on Windows 7 64-bits.

That's it :-)

Mel Smith : From CA-Clipper to xHarbour+HMG

CCH: On reading a email from Sudip regarding Mel Smith's migration from CA-Clipper to xHarbourt+HMG, I wrote to Mel Smith on 16th March 2009 and obtained his consent to republish it here.

Mel Smith to Sudip

Sudip,

Many people are starting to use the 'IDE' method (and, apparently successfully).

However, I am 'old-fashioned' and so I hand-code everything, and I use the 'HBMAKE.EXE' utility of xHarbour to build my apps.

If you provide me with an email address that allows attachments (btw, Gmail does *not* allow attachments), I will forward my BLD.BAT file, my xxx.BC file that is a parameter to HBMAKE, and my main app plus one other module for you to see how I proceed.

My conversion procedure is usually:

1. Make a copy of the original Clipper 5.2e program and all its various modules
2. Convert this copy to proper xHarbour (fixing all previous bad styles to proper styling, etc, etc)
3. With all modules converted to xHarbour, run this console-style program to ensure it works as good or better than the Clipper app
4. Start windowizing:
a. Start with the Function Main() and build a main window.
b. Add the main menu to this window
c. In one of the menu options, call/activate a simple sub-function (e.g., build all indexes)
d. Go to this sub function and add a child window and carry on with the conversion.
e. Go to c. again :)))

I have included the Main Window definition from the Main Function from one of my apps below:


... there are 1480 lines of setup before the following initialization of the app's Main Window ...

BTW, I had an old app named ACT (for Accounting -- I always use 3 letters for my various apps)
When I started converting to 'windows' I just added a 'W' to the beginning of 'ACT' . Thus, WACT is the app name
Please don't assume the code below is 'Good' or 'Sophisticated'. It is *not* ! It is just *my* conversion of old stuff. But it does work., and it is quite simple. There are about 48 separated modules I had to convert. The fragment below is part of the Main module

You will note that some of the conversion has not been required or completed yet (i.e., the donothing() function refers to this

...
...
SET MULTIPLE OFF

SET NAVIGATION EXTENDED
cWIN := "WACT"

DEFINE WINDOW WACT ;
AT nMTOP,nMLEFT ;
WIDTH nMWIDTH HEIGHT nMHEIGHT ;
TITLE "Accounting Control for A/P, A/R and Payroll: " + GVERSION + ;
" ( on Drive " + GNETDRV+" )" + " Process Date : " + GTHEN ;
ICON "WORLD" ;
FONT "Arial" SIZE 12 ;
MAIN ;
ON INIT {|| (IIF(lRBLDIDX,(WACT.LABNDX.SHOW,WACT.NDXFIL.SHOW, ;
WACT.INDEXPROG.SHOW,RBLDIDX(lSETUPDBF:=.T.)),), ;
WACT.LABNDX.HIDE,WACT.NDXFIL.HIDE,WACT.INDEXPROG.HIDE, ;
(GABORT := .NOT. SETUPDATES(GDATE), ;
IIF(GABORT,DOMETHOD("WACT","RELEASE"),.T.)), ;
SETSTATUS(cWINSTATUS:=" Ready for Menu Selection"))}

DEFINE MAIN MENU
POPUP "Accounts &Payable"
ITEM " 1. Add/Edit A/P Transactions" ACTION {||MNTPAY(),DBCLOSEALL()}
ITEM " 2. Add/Edit C/R Transactions" ACTION DONOTHING() DISABLED
ITEM " 3. Load Suppliers" ACTION DONOTHING() DISABLED
ITEM " 4. Update Supplier A/P File" ACTION DONOTHING() DISABLED
ITEM " 5. Update Purchase Order File" ACTION {||MNTPCH(),DBCLOSEALL()}
ITEM " 6. Fix Vend Acct. Nos. in A/P" ACTION DONOTHING() DISABLED
ITEM " 7. P.O Report Menu" ACTION DONOTHING() DISABLED
ITEM " 8. A/P Reports / Cheques Menu" ACTION {||PAYREPS(),DBCLOSEALL()}
ITEM " 9. C/R Reports / Cheques Menu" ACTION DONOTHING() DISABLED
ITEM " A. Multi-Job Costing Tables" ACTION {|| LOADCOST("WACT"),DBCLOSEALL(), ;
SETPROPERTY("WACT","oSTOPSCAN","VISIBLE",.F.), ;
SETPROPERTY("WACT","oSTOPSCAN","ENABLED",.F.)}
ITEM " B. Job Costing for ONE Job" ACTION {||MNTJCS(),DBCLOSEALL()}
ITEM " X. Exit" ACTION DOMETHOD("WACT","Release")
END POPUP

POPUP "Accounts &Receivable"
ITEM " 1. Add/Edit A/R Transactions" ACTION DONOTHING() DISABLED
ITEM " 2. Fix Cust No. in A/R File " ACTION DONOTHING() DISABLED
ITEM " 3. Edit Customer Information" ACTION DONOTHING() DISABLED
ITEM " 4. Edit Customer Financials " ACTION DONOTHING() DISABLED
ITEM " 5. " ACTION DONOTHING() DISABLED
ITEM " 6. Receipts Input Processing" ACTION DONOTHING() DISABLED
ITEM " 7. " ACTION DONOTHING() DISABLED
ITEM " 8. Print Reports / Invoices " ACTION DONOTHING() DISABLED
ITEM " 9. " ACTION DONOTHING() DISABLED
ITEM " A. Change Txn Number Format " ACTION DONOTHING() DISABLED
ITEM " B. Import Spreadsheet Data " ACTION DONOTHING() DISABLED
END POPUP

POPUP "&Utilities"
ITEM " 1. View/Edit G/L Master " ACTION DONOTHING() DISABLED
ITEM " 2. View Admin Passwords " ACTION DONOTHING() DISABLED
ITEM " 3. Load C/R Register File" ACTION DONOTHING() DISABLED
ITEM " 4. Load G/L Accounts File" ACTION DONOTHING() DISABLED
ITEM " 5. Load Time-Sheet Files " ACTION DONOTHING() DISABLED
ITEM " 6. Load Employee File " ACTION DONOTHING() DISABLED
ITEM " 7. Re-Build Vendor Codes " ACTION DONOTHING() DISABLED
ITEM " 8. Set-Up P.O. Remarks " ACTION DONOTHING() DISABLED
ITEM " 9. Set-Up Div/EWO DBFs " ACTION DONOTHING() DISABLED
ITEM " A. Set-Up Work-Area DBFs " ACTION DONOTHING() DISABLED
END POPUP

POPUP "&Employees"
ITEM " 1. Browse Employee File " ACTION DONOTHING() DISABLED
ITEM " 2. Browse Job Desc File " ACTION DONOTHING() DISABLED
ITEM " 3. Browse Rates/Deductions " ACTION DONOTHING() DISABLED
ITEM " 4. Time-Sheet Entry System " ACTION {||MNTTBS(),DBCLOSEALL()}
ITEM " 5. Print Time and Expenses " ACTION {||TBSREPS(),DBCLOSEALL()}
ITEM " 6. Print Payroll Cheques " ACTION DONOTHING() DISABLED
ITEM " 7. Period-End Payroll " ACTION DONOTHING() DISABLED
ITEM " 8. Load Employees (AccPac) " ACTION DONOTHING() DISABLED
ITEM " 9. View TBS Time-Sheets " ACTION DONOTHING() DISABLED
ITEM " A. Browse Unions File " ACTION DONOTHING() DISABLED
END POPUP

POPUP "&Manager"
ITEM " 1. Rebuild Index Files" ACTION RBLDIDX(lSETUPDBF:=.T.)
ITEM " 2. Edit Company Information" ACTION {|| MNTSYS(),DBCLOSEALL()}
ITEM " 3. Run old DOS ACT System" ACTION DOOLDACT("WACT")
ITEM " 4. View / Edit Job Status" ACTION {|| MNTJOB("WACT"),DBCLOSEALL()}
ITEM " 5. View / Edit Job Rates" ACTION {|| MNTJRT(),DBCLOSEALL()}
ITEM " 6. Print Job(s) Status" ACTION DONOTHING() DISABLED
ITEM " 7. Test Send of Email" ACTION SENDMAIL()
ITEM " X. Exit" ACTION DOMETHOD("WACT","Release")
END POPUP

END MENU

@ (nMBOT-nMTOP)/2 - 40, 150 LABEL LABNDX AUTOSIZE ;
VALUE "Indexing File : " ;
INVISIBLE

cFIL2NDX := SPACE(20)

@ (nMBOT-nMTOP)/2 - 40, 300 TEXTBOX NDXFIL VALUE cFIL2NDX ;
WIDTH 300 ;
INVISIBLE

@ (nMBOT-nMTOP)/2,150 PROGRESSBAR INDEXPROG ;
RANGE 0,10000 ;
WIDTH 600 ;
HEIGHT 30 ;
SMOOTH ;
INVISIBLE ;
TOOLTIP "Indexing Progress"


@ nMBOT-86,000 LABEL STATPMPT OF WACT AUTOSIZE ;
VALUE "Status Line->" ;
FONT "Arial" SIZE 10

@ nMBOT-86,100 LABEL STATLINE OF WACT ;
VALUE cWINSTATUS ;
WIDTH 500 HEIGHT 30 ;
FONT "Arial" SIZE 10 ;
BOLD

@ nMCTRROW-(nBUTTH),nMCTRCOL-(nBUTTH) BUTTONEX oSTOPSCAN OF WACT;
CAPTION "Stop Scan"+CRLF+"of Job Cost"+CRLF+"Databases" ;
WIDTH nBUTTW+30 ;
HEIGHT nBUTTH+40 ;
FONTCOLOR RED ;
BACKCOLOR YELLOW ;
NOTABSTOP ;
BOLD ;
INVISIBLE ;
ACTION {||lESCPRESSED := .T.}

WACT.oSTOPSCAN.ENABLED := .F.
WACT.oSTOPSCAN.VISIBLE := .F.

ON KEY ESCAPE OF WACT ACTION {||nESCKEY:=K_ESC,THISWINDOW.RELEASE}

END WINDOW

Mel Smith

Adding GUI to xHarbour/Harbour via HMG [Part I]

I started with FAS4XHB, the migrated FAS4DOS mentioned in my earlier articles as follows :


After Adding MENU structure using HMG

Having downloaded the Harbour MiniGui Harbour Distribution and joining the HMG Forum, I played with the IDE. Nice.. but on the advice of Esgici, I started to code by hand this morning and this is the result of my handiwork :-



After adding a Status Bar showing Date & Time..

DEFINE STATUSBAR
CLOCK
DATE
END STATUSBAR



After adding a Tool Bar with some high quality bitmaps :-

DEFINE TOOLBAR ToolBar_1 BUTTONSIZE 32,24 BORDER

BUTTON Button_Exit ;
CAPTION 'E&xit' ;
PICTURE 'exit.bmp' ;
ACTION Exit()
SEPARATOR

BUTTON Button_GL ;
CAPTION '&General Ledger' ;
PICTURE 'accounts.bmp' ;
ACTION ViewGL()

BUTTON Button_AR ;
CAPTION 'Accounts &Receivable' ;
PICTURE 'table.bmp' ;
ACTION ViewAR()

BUTTON Button_AP ;
CAPTION 'Accounts &Payable' ;
PICTURE 'view.bmp' ;
ACTION ViewAP()
SEPARATOR

BUTTON Button_Reindex ;
CAPTION '&Reindex All' ;
PICTURE 'task-2.bmp' ;
ACTION ReindexAll()
END TOOLBAR


Now, it looks pretty good for a Clipper for Windows (Harbour+HMG) executable !

Why you should recompile your CA-Clipper DOS applications to Win32

CA-Clipper for DOS was, once hugely popular amongst Xbase programmers from Summer'87 right up to Version 5.2e. Apparently, 5.3 onwards were not vey popular. Even now, it is amazing to discover that there are still many CA-Clipper programmers out there. However, CA-Clipper for DOS programs don't do well under Windows, and may not run at all in Win'98, ME, XP , Vista or on fast processors, or they may have problems printing. In addition , the interface is text-based , hogs processor time which slows everything else down, and can't communicate with Windows programs.

So what's the solution & I am not talking of GUI ?

Simple, recompile your existing CA-Clipper source codes using a 32-bit CA-Clipper compatible compilers such as the Harbour Project, xHarbour or Xbase++. If you prefer open-source the Harbour Project & xHarbour will definitely be your choice. However, if you require more support, I guess that xHarbour.com & Xbase++ will be the way to go.

Clarification from Ron Pinkas

xHarbour is first and foremost a free open source project, exactly as
Harbour.

In *addition* to being completely free, it's *also* distributed by
xHarbour.com, as a commercial distribution that includes numerous Add-on
Tools & Libraries, as well as tech support services.

Needless to say, the existence of the xHarbour.com commercial distribution
does not take away from the freedom of xHarbour, the opposite it provides
even more resources to the free project.

So what are the benefits of having your familiar CA-Clipper application as a true Windows 32-bit Executable ?

A quick list of the benefits of being a true Windows application is that it can:

• Utilize all the available memory, no more DOS boundaries
• Use bigger sized variables, no more limits such as 4096 array elements, 64K data segment, etc.
• Use any kind of printer installed on Windows, including network printer, Fax printer, PDF printer, etc.
• Use Windows resources easily, eg. clipboard, common dialogs, etc
• Collaborate with other Windows application, eg. Excel, Internet Explorer, etc.

You may want to read about my own experience in porting a sizeable real-life Accounting application (still in use in some customers) from CA-Clipper 5.2e to xHarbour

• Migrating from CA-Clipper 5.2e to xHarbour (Part I)
• Migrating from CA-Clipper 5.2e to xHarbour (Part II)
• Migrating from CA-Clipper 5.2e to xHarbour (Part III)- Updated 2nd March 2009
  

How to add code created by Visual xHarbour to a xHarbour Application [Updated 25th Feb 2009]

As you are probably aware, CA-Clipper codes can readily be recompiled in Xharbour into a W32 executable. In my scenario, I have a complex processing engine originally written in CA-Clipper 5.2e which can then be called within my Delphi applications

I had earlier used CA-Clipper 5.2e +Fivewin to create a W16 executable which was then called via winexec() from my Delphi Application. Being 16-bits meant that NTVDM was called automatically by Windows. What I wanted was a true W32 executable which will not require the usage of NTVDM.

There are 2 scenarios involved
1) Automatic processing without user input
2) Need for user input before automatic processing takes place

For Scenario 1, all I needed was to recompiled in Xharbour to transform my 5.2e CA-Clipper Codes into a 32-bit true windows application. It is that easy :-)

For Scenario 2, I needed user to input a parameter. Problem is that XHarbour does not have a simple Window Dialog function such as Delphi's InputQuery. So what's the solution ?

The Solution

1) Use Visual xHarbour (VXH) to create a windows form with
a) label control named MessageLabel
b) edit control named InputValueEdit
c) button control named OKBtn
d) button control named CancelBtn

2) Saved the Windows Form as

//MsgGetForm.prg

GLOBAL EXTERNAL Application
GLOBAL cMessage
GLOBAL cCaption
GLOBAL cInputValue

#include "vxh.ch"
#include "MsgGetForm.xfm"
//---------------------------------------- End of system code ----------------------------------------//

//----------------------------------------------------------------------------------------------------//
METHOD CancelBtn_OnClick( Sender ) CLASS MsgGetForm
::close()
RETURN Self
//----------------------------------------------------------------------------------------------------//
METHOD MsggetForm_Form_OnActivate( Sender ) CLASS MsgGetForm
::MessageLabel:caption:=cMessage
::caption:=cCaption
::InputValueEdit:caption:=cInputValue

RETURN Self
//----------------------------------------------------------------------------------------------------//
METHOD OKBtn_OnClick( Sender ) CLASS MsgGetForm
cInputValue:= ::InputValueEdit:Caption
::close()
RETURN Self


MsgGet_XFM.prg (automatically generated by VXH)

#include "vxh.ch"
//---------------------------------------- End of system code ----------------------------------------//

//------------------------------------------------------------------------------------------------------------------------------------

CLASS __MsgGet INHERIT Application
// Components declaration
// Controls declaration
METHOD Init() CONSTRUCTOR

// Event declaration
ENDCLASS

METHOD Init( oParent ) CLASS __MsgGet
::Super:Init( oParent )


// Populate Components
// Properties declaration

::Create()

// Populate Children
RETURN Self

//MsgGetForm.xfm (text definition based on the window form created with VHB)
//---------------------------------------------------------------------------------------------------------------------------------
//
CLASS MsgGetForm INHERIT WinForm
// Components declaration
// Controls declaration
DATA MessageLabel EXPORTED
DATA InputValueEdit EXPORTED
DATA OKBtn EXPORTED
DATA CancelBtn EXPORTED
METHOD Init() CONSTRUCTOR

// Event declaration
METHOD MsggetForm_Form_OnActivate()
METHOD OKBtn_OnClick()
METHOD CancelBtn_OnClick()

ENDCLASS

METHOD Init( oParent ) CLASS MsgGetForm
::Super:Init( oParent )

::EventHandler[ "OnActivate" ] := "MsggetForm_Form_OnActivate"

// Populate Components
// Properties declaration
::Left := 10
::Top := 10
::Width := 534
::Height := 139
::Name := "MsgGetForm"
::Caption := "MsgGetFormCaption"
::ClipChildren := .T.
::ClipSiblings := .T.

::Create()

// Populate Children
WITH OBJECT ( ::MessageLabel := LABEL( Self ) )
:Left := 41
:Top := 8
:Width := 160
:Height := 16
:Name := "MessageLabel"
:Caption := "MessageLabel"
:Border := .F.
:ClipChildren := .T.
:ClipSiblings := .T.
:TabStop := .F.
:Create()
END //MessageLabel

WITH OBJECT ( ::InputValueEdit := EDIT( Self ) )
:Left := 41
:Top := 32
:Width := 445
:Height := 22
:Name := "InputValueEdit"
:ClientEdge := .T.
:Border := .F.
:ClipSiblings := .T.
:Create()
END //InputValueEdit

WITH OBJECT ( ::OKBtn := BUTTON( Self ) )
:Left := 178
:Top := 61
:Width := 77
:Height := 30
:Name := "OKBtn"
:Caption := "&OK"
:Border := .F.
:ClipChildren := .T.
:ClipSiblings := .T.
:EventHandler[ "OnClick" ] := "OKBtn_OnClick"
:Create()
END //OKBtn

WITH OBJECT ( ::CancelBtn := BUTTON( Self ) )
:Left := 268
:Top := 62
:Width := 79
:Height := 31
:Name := "CancelBtn"
:Caption := "&Cancel"
:Border := .F.
:ClipChildren := .T.
:ClipSiblings := .T.
:EventHandler[ "OnClick" ] := "CancelBtn_OnClick"
:Create()
END //CancelBtn

::Show()

RETURN Self


2) Next, I added a wrapper function MsgGet() function in my Main.prg

// function in msggetform.prg
FUNCTION MsgGet(cFormCaption,cFormMessage,cFormInputValue)
// GLOBALs in MsgGetForm.prg
cMessage:=cFormMessage
cCaption:=cFormCaption
cInputValue:=cFormInputValue
__MsgGet( NIL ):Run( MsgGetForm( NIL ), HB_aParams() )


RETURN cInputValue

3) In the calling prg

cRetVal:=MsgGet('Create Data','Input No. of Working Days', @mNo_of_days)

That's it !

What is my wish list for the xHarbour people ? Provide a standard windows function as part of xHarbour :-)

Comments from David A. Smith , comp.lang.xHarbour
Some options are:
1) make a DLL of your "scenario" code, and call it as an unloadable library. (Not sure if there are limitations on collecting user input in a DLL.)
2) call your "scenario" code via OLE / xBScript
3) do it the way you have been doing it, just translate / recompile.

From Clipper to Harbour - Viktor Szakáts

Date : Mon, 16 Feb 2009 10:40:57 +0100
Subject : Re: Long time no see

VICTOR : Hi Chong Hwa,
Nice to see you reviving Clipper...Clipper...Clipper.
It's been a long time :) I hope you're well.

CCH: Well, it's been more than 10 years :-)

VICTOR : Yep. I'm glad you remember.

VICTOR : If you're interested, I invite you to join Harbour's developer list,
it'd be great to see you there.

CCH: TQ and I am honoured by your invitation.
However, work commitments does not me to do so :-)

VICTOR : I can understand that, you're welcome any time in the future.

CCH: I would love to publish an article from you showing how you switched
from Clipper to Harbour. I am OK with xHarbour but I must admit I am a little lost on how to do it with Harbour.

From Clipper to Harbour - Viktor Szakáts

From a user's POV they are probably the same. Maybe there are some aspects of xhb which I don't know and could make the process different, but normally it's just a recompile and relink, feature-wise Harbour is on par with xhb, and a plus Harbour is cleaner, more robust, more portable and faster, it also has an xhb.lib which aims to provide compatibility with
features we've opted not to include in the core product.

I've just finished a new hbmk (Harbour Make) utility this weekend.

My transition was a long, gradual process, while keeping continuous Clipper releases and focusing on minimizing any risks on the user side, while maturing the Harbour release versions.

Also, the process was two fold:

1) Transition to Harbour for Windows.

2) Transition to be multi platform in general, allowing
easy move to any other platforms in the future.
This mostly comes down to file system / OS environment
differences.

Here are the main stages (and the devils are in the details :):

1) Departing from DOS/Windows concepts like case-insensitive filenames, drive letters and any other possible platform dependencies, like using some specific external tools. This was done by keeping Clipper compatibility, where this was impossible it was added using conditional code.

2) Some libs/tools which didn't have a Harbour/portable version, had to be replaced by new parts and sometimes concepts. One such is Telepath(y), which got replaced by curl, then hbcurl.

3) Adjusting all own .c functions for Harbour Windows version, using conditional code.

4) Added simple make system for Harbour Windows versions.

5) Created first running Harbour version for Windows and started testing locally plus a few clients.

6) After filling all missing bits in Harbour, there was time for the show to begin by creating the first official Harbour builds of the apps. Points below took 3-6 months depending on how we count it.

7) This quickly turned out to be a success since as apps were proved to run very stable, now the main work could begin by now being able to drop all Clipper heritage.

8) Created new local build systems for all parts, this time keeping in mind Linux/Darwin compatibility.

9) Started optimizing speed by refining the compiler choice and Harbour and local app build options.

10) After removing dependency on Clipper, the code could be moved from Clipper compatibility mode to Harbour native mode. This allowed to drop many functions and replace them with Harbour functions, tools and libs. This solved some rare problems with the apps, caused by bugs in local .c code. In fact I've reduced local .c code to an absolute minimum. This stage also resulted in noticeable speed up in certain points of the application.

11) The apps were now ported to Linux/Darwin with minimal effort.

12) Now fun part could be started, really start to exploit the possibilities of the new platforms and Harbour. I'm doing this since months and it's really a breath of fresh air.

Since I'm a main contributor to Harbour, all this was accompanied by parallel Harbour development, fixing incompatibilities, some bugs, finding all missing points and filling the gaps, and creating stable releases.

In the last few years the main areas to fill were TBROWSE, some multi-platform file handling stuff for the most part, and some stuff related to codepages. Currently using the latest SVN, which is practically release quality.

I hope that helps or is useful in any ways.

Brgds,

Viktor Szakáts